Deplasarea unui personaj de la dreapta la stanga folosind ActionScript

// Aceasta variabila controleaza viteza de mers pe orizontala
var speedX:Number = 10;
var speedY:Number = 4;
 
// o functie pe care o rulam cand flash deschide proiectul.
function startActionScript(){
    
    //cream un key listener ca sa putem atasa evenimente
    //de 'KeyDown' si 'KeyUp'
    var keyListener:Object = new Object();
    
    //atat timp cat este apasata o tasta, se executa urm. script
    keyListener.onKeyDown = function() {
        //functie care se executa la fiecare milisecunda cat timp
        //este apasata o tasta
        man_mc.onEnterFrame = function() {
            //daca s-a apasat tasta 'sageata Dreapta'; 
            //deplasare pe orizontala
            if (Key.isDown(Key.RIGHT)) {
                //daca suntem inca pe suprafata mesei, 
                //deplasam obiectul la dreapta
                var limitRight = ground_mc._x + ground_mc._width 
                                 - this._width
                if (this._x + speedX <= limitRight)
                    this._x += speedX;
            } 
            //daca s-a apasat tasta 'sageata Stanga'; 
            //deplasare pe orizontala
            else if (Key.isDown(Key.LEFT)) {
                //daca suntem inca pe suprafata mesei, 
                //deplasam obiectul la stanga
                var limitLeft = ground_mc._x;
                if (this._x - speedX >= limitLeft)
                    this._x -= speedX;
            }
            //daca s-a apasat tasta 'sageata Sus'; 
            //deplasare pe verticala
            else if (Key.isDown(Key.UP)){
                if (this._y - speedX > 0){
                    this._y -= speedX;
                }
                
            }
            //daca s-a apasat tasta 'sageata Jos'; 
            //deplasare pe verticala
            else if (Key.isDown(Key.DOWN)){
                if (this._y + speedX < ground_mc._y - this._height){
                    this._y += speedX;
                }
            }
        }
    }
    
    //dupa ce s-a dat drumul la tasta, se executa urm. script
    keyListener.onKeyUp = function() {
        //stergem functia 'onEnterFrame' a obiectului 'man_mc'
        delete man_mc["onEnterFrame"];
        
        //daca obiectul nostru nu se afla pe masa, este in aer
        if (man_mc._y  < ground_mc._y - man_mc._height){
            //functie care se executa la fiecare milisecunda cat timp
            //obiectul nu se afla pe suprafata mesei
            man_mc.onEnterFrame = function() {
                if (this._y  < ground_mc._y - this._height){
                    this._y +=speedY;
                }
                else{
                    this._y = ground_mc._y - this._height;
                    delete man_mc["onEnterFrame"];
                }
            }
        }
    }
    //atasam obiectul 'keyListener' clasei KEY
    Key.addListener(keyListener);
        
}
 
//pornim scriptul
startActionScript();